Mercurial > hg > CbC > CbC_gcc

comparison config/gettext-sister.m4 @ 0:a06113de4d67

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
first commit
author kent <kent@cr.ie.u-ryukyu.ac.jp>
date Fri, 17 Jul 2009 14:47:48 +0900
parents
children
comparison
equal deleted inserted replaced
-1:000000000000 0:a06113de4d67
1 # intl sister-directory configuration rules.
2 #
3
4 # The idea behind this macro is that there's no need to repeat all the
5 # autoconf probes done by the intl directory - it's already done them
6 # for us. In fact, there's no need even to look at the cache for the
7 # answers. All we need to do is nab a few pieces of information.
8 # The intl directory is set up to make this easy, by generating a
9 # small file which can be sourced as a shell script; then we produce
10 # the necessary substitutions and definitions for this directory.
11
12 AC_DEFUN([ZW_GNU_GETTEXT_SISTER_DIR],
13 [# If we haven't got the data from the intl directory,
14 # assume NLS is disabled.
15 USE_NLS=no AC_SUBST(USE_NLS)
16 LIBINTL= AC_SUBST(LIBINTL)
17 LIBINTL_DEP= AC_SUBST(LIBINTL_DEP)
18 INCINTL= AC_SUBST(INCINTL)
19 XGETTEXT= AC_SUBST(XGETTEXT)
20 GMSGFMT= AC_SUBST(GMSGFMT)
21 POSUB= AC_SUBST(POSUB)
22
23 if test -f ifelse([$1],,[../intl],[$1])/config.intl; then
24 . ifelse([$1],,[../intl],[$1])/config.intl
25 fi
26 AC_MSG_CHECKING([whether NLS is requested])
27 if test x"$USE_NLS" != xyes; then
28 AC_MSG_RESULT(no)
29 else
30 AC_MSG_RESULT(yes)
31 AC_DEFINE(ENABLE_NLS, 1,
32 [Define to 1 if translation of program messages to the
33 user's native language is requested.])
34
35 AC_MSG_CHECKING(for catalogs to be installed)
36 # Look for .po and .gmo files in the source directory.
37 CATALOGS= AC_SUBST(CATALOGS)
38 XLINGUAS=
39 for cat in $srcdir/po/*.gmo $srcdir/po/*.po; do
40 # If there aren't any .gmo files the shell will give us the
41 # literal string "../path/to/srcdir/po/*.gmo" which has to be
42 # weeded out.
43 case "$cat" in *\**)
44 continue;;
45 esac
46 # The quadruple backslash is collapsed to a double backslash
47 # by the backticks, then collapsed again by the double quotes,
48 # leaving us with one backslash in the sed expression (right
49 # before the dot that mustn't act as a wildcard).
50 cat=`echo $cat | sed -e "s!$srcdir/po/!!" -e "s!\\\\.po!.gmo!"`
51 lang=`echo $cat | sed -e "s!\\\\.gmo!!"`
52 # The user is allowed to set LINGUAS to a list of languages to
53 # install catalogs for. If it's empty that means "all of them."
54 if test "x$LINGUAS" = x; then
55 CATALOGS="$CATALOGS $cat"
56 XLINGUAS="$XLINGUAS $lang"
57 else
58 case "$LINGUAS" in *$lang*)
59 CATALOGS="$CATALOGS $cat"
60 XLINGUAS="$XLINGUAS $lang"
61 ;;
62 esac
63 fi
64 done
65 LINGUAS="$XLINGUAS"
66 AC_MSG_RESULT($LINGUAS)
67
68 dnl Set up some additional variables which our po/Make-in files
69 dnl may need.
70
71 dnl For backward compatibility. Some Makefiles may be using these.
72 DATADIRNAME=share
73 AC_SUBST(DATADIRNAME)
74 INSTOBJEXT=.mo
75 AC_SUBST(INSTOBJEXT)
76 GENCAT=gencat
77 AC_SUBST(GENCAT)
78 CATOBJEXT=.gmo
79 AC_SUBST(CATOBJEXT)
80 fi])