Mercurial > hg > CbC > CbC_gcc

comparison libmudflap/configure.ac @ 0:a06113de4d67

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
first commit
author kent <kent@cr.ie.u-ryukyu.ac.jp>
date Fri, 17 Jul 2009 14:47:48 +0900
parents
children 77e2b8dfacca
comparison
equal deleted inserted replaced
-1:000000000000 0:a06113de4d67
1 # Process this file with autoconf to produce a configure script, like so:
2 # aclocal -I .. -I ../config && autoconf && autoheader && automake
3
4 AC_PREREQ(2.59)
5 AC_INIT(libmudflap, 1.0)
6 AC_CONFIG_SRCDIR(mf-runtime.c)
7 AC_CANONICAL_SYSTEM
8 ACX_NONCANONICAL_TARGET
9
10 AM_INIT_AUTOMAKE
11
12 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
13 AC_ARG_ENABLE(version-specific-runtime-libs,
14 [ --enable-version-specific-runtime-libs Specify that runtime libraries should be installed in a compiler-specific directory ],
15 [case "$enableval" in
16 yes) version_specific_libs=yes ;;
17 no) version_specific_libs=no ;;
18 *) AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
19 esac],
20 [version_specific_libs=no])
21 AC_MSG_RESULT($version_specific_libs)
22
23 AM_MAINTAINER_MODE
24 AC_EXEEXT
25
26 AM_ENABLE_MULTILIB(, ..)
27
28 target_alias=${target_alias-$host_alias}
29 AC_SUBST(target_alias)
30
31 AC_CONFIG_HEADERS(config.h)
32
33 AC_LANG_C
34 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
35 # We must force CC to /not/ be precious variables; otherwise
36 # the wrong, non-multilib-adjusted value will be used in multilibs.
37 # As a side effect, we have to subst CFLAGS ourselves.
38
39 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
40 m4_define([_AC_ARG_VAR_PRECIOUS],[])
41 AC_PROG_CC
42 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
43
44 AC_SUBST(CFLAGS)
45
46 if test "x$GCC" != "xyes"; then
47 AC_MSG_ERROR([libmudflap must be built with GCC])
48 fi
49 AC_PROG_CPP
50
51 # Some hosts don't have dlsym(RTLD_NEXT, "symbol") for use in
52 # symbol interposition. We disable shared libraries for these.
53 AC_MSG_CHECKING([whether dlsym(RTLD_NEXT,...) is available])
54 AC_TRY_COMPILE([
55 #define _GNU_SOURCE
56 #include <dlfcn.h>
57 ],
58 [void *foo = dlsym (RTLD_NEXT, "exit");],
59 [AC_MSG_RESULT(yes)],
60 [AC_MSG_RESULT(no)
61 enable_shared=no])
62
63 AC_CHECK_HEADERS(stdint.h execinfo.h signal.h dlfcn.h dirent.h pwd.h grp.h \
64 netdb.h sys/ipc.h sys/sem.h sys/shm.h sys/wait.h ctype.h mntent.h \
65 sys/socket.h netinet/in.h arpa/inet.h dlfcn.h sys/mman.h)
66
67 AC_CHECK_FUNCS(backtrace backtrace_symbols gettimeofday signal)
68 AC_CHECK_FUNCS(fopen64 fseeko64 ftello64 stat64 freopen64)
69 AC_CHECK_FUNCS(setbuf setbuffer setlinebuf setvbuf)
70 AC_CHECK_FUNCS(strnlen memrchr strncpy memmem sethostname)
71 AC_CHECK_FUNCS(__ctype_b_loc __ctype_tolower_loc __ctype_toupper_loc)
72 AC_CHECK_FUNCS(getlogin cuserid getpwnam getpwuid getpwent getgrnam getgrgid getgrent)
73 AC_CHECK_FUNCS(getlogin_r getpwnam_r getpwuid_r getgrnam_r getgrgid_r)
74 AC_CHECK_FUNCS(getservent getservbyname getservbyport getaddrinfo gai_strerror)
75 AC_CHECK_FUNCS(getprotoent getprotobyname getprotobynumber)
76 AC_CHECK_FUNCS(getmntent setmntent addmntent)
77 AC_CHECK_FUNCS(inet_ntoa mmap munmap)
78 AC_CHECK_FUNCS(__libc_freeres)
79
80 AC_TRY_COMPILE([#include <sys/types.h>
81 #include <sys/ipc.h>
82 #include <sys/sem.h>],[union semun foo;], [mf_have_semun=1], [mf_have_semun=0])
83 if test $mf_have_semun = 1
84 then
85 AC_DEFINE(HAVE_UNION_SEMUN, 1, [union semun defined in sys/ipc.h or sys/sem.h])
86 fi
87
88
89 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
90 AC_TRY_COMPILE([#define _POSIX_PII_SOCKET
91 #include <sys/types.h>
92 #include <sys/socket.h>], [socklen_t x = 5;],
93 [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
94 AC_MSG_RESULT(yes)],
95 [AC_MSG_RESULT(no)])
96
97 AC_LIBTOOL_DLOPEN
98 AM_PROG_LIBTOOL
99 AC_SUBST(enable_shared)
100 AC_SUBST(enable_static)
101
102 AC_CHECK_HEADER(stdint.h, [MF_HAVE_STDINT_H=1], [MF_HAVE_STDINT_H=0])
103 AC_SUBST(MF_HAVE_STDINT_H)
104 if test $MF_HAVE_STDINT_H = 1
105 then
106 MF_HAVE_UINTPTR_T=1
107 else
108 AC_TRY_COMPILE([#include <sys/types.h>], [uintptr_t k = 0;],
109 [MF_HAVE_UINTPTR_T=1], [MF_HAVE_UINTPTR_T=0])
110 fi
111 AC_SUBST(MF_HAVE_UINTPTR_T)
112
113 if test ! -d pth
114 then
115 # libmudflapth objects are built in this subdirectory
116 mkdir pth
117 fi
118
119 AC_CHECK_HEADERS(pthread.h)
120
121 AC_MSG_CHECKING([for thread model used by GCC])
122 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
123 AC_MSG_RESULT([$target_thread_file])
124
125 # We only support posix threads, or no threads at all.
126 posix_threads=
127 case ${target_thread_file} in
128 posix)
129 posix_threads=yes
130 ;;
131 single)
132 ;;
133 *)
134 echo "${target_thread_file} is an unsupported thread package" 1>&2
135 exit 1
136 ;;
137 esac
138
139 AM_CONDITIONAL(LIBMUDFLAPTH, [test "x$posix_threads" != "x"])
140 if test "x$posix_threads" != "x"
141 then
142 build_libmudflapth=1
143 else
144 build_libmudflapth=0
145 fi
146 AC_SUBST(build_libmudflapth)
147
148 AC_CHECK_LIB(dl, dlsym)
149
150 # Calculate toolexeclibdir
151 # Also toolexecdir, though it's only used in toolexeclibdir
152 case ${version_specific_libs} in
153 yes)
154 # Need the gcc compiler version to know where to install libraries
155 # and header files if --enable-version-specific-runtime-libs option
156 # is selected.
157 toolexecdir='$(libdir)/gcc/$(target_alias)'
158 toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
159 ;;
160 no)
161 if test -n "$with_cross_host" &&
162 test x"$with_cross_host" != x"no"; then
163 # Install a library built with a cross compiler in tooldir, not libdir.
164 toolexecdir='$(exec_prefix)/$(target_alias)'
165 toolexeclibdir='$(toolexecdir)/lib'
166 else
167 toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
168 toolexeclibdir='$(libdir)'
169 fi
170 multi_os_directory=`$CC -print-multi-os-directory`
171 case $multi_os_directory in
172 .) ;; # Avoid trailing /.
173 *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
174 esac
175 ;;
176 esac
177 AC_SUBST(toolexecdir)
178 AC_SUBST(toolexeclibdir)
179
180 includedir=${toolexecdir}/include
181 AC_SUBST(includedir)
182
183 pthread_create_version='""'
184 if test "x$enable_shared" = "xyes" && test "x$posix_threads" != "x"; then
185 # NB: don't check for -lpthread here, because then it would be
186 # added to LIBS. For the thread-unaware libmudflap.la, we don't
187 # want it there.
188
189 # glibc-related hacks. dlsym() may pick the wrong version of
190 # interposed functions like pthread_create on modern glibc.
191 # We need to find the proper symbol version string, and use
192 # the nonstandard dlvsym().
193 AC_CHECK_FUNCS(dlvsym)
194 AC_CHECK_TOOL(NM, nm)
195 if test "x$ac_cv_have_dlvsym" != "x"; then
196 # Try compiling a simple pthreads program. Find the shared libraries it
197 # ends up with. Then use "nm" on those libraries to extract the
198 # default symbol versioning suffix ("@@"), if any. But that's tricky.
199 # Rather, run nm on the resulting executable. Unfortunately, autoconf
200 # doesn't appear to have a macro that builds a test executable for
201 # subsequent analysis ... so we do it by hand here.
202 cat >> conftest.c << EOF
203 #include <pthread.h>
204 int main () { void *p = (void *) & pthread_create; return (int) p; }
205 EOF
206 oldLIBS="$LIBS"
207 LIBS="$LIBS -lpthread"
208 pthread_create_version="\"\""
209 AC_MSG_CHECKING(pthread_create symbol version)
210 if eval $ac_link 2>&5 && test -s conftest${ac_exeext}; then
211 version=`$NM conftest${ac_exeect} | grep 'pthread_create@@' | sed -e 's/^.*@@//'`
212 if test "x$version" != "x"; then
213 pthread_create_version="\"$version\""
214 fi
215 fi
216 AC_MSG_RESULT($pthread_create_version)
217 LIBS="$oldLIBS"
218 fi
219 fi
220 AC_DEFINE_UNQUOTED(PTHREAD_CREATE_VERSION, $pthread_create_version, [pthread_create symbol version])
221
222
223 # Figure out whether the compiler supports "-ffunction-sections -fdata-sections",
224 # similarly to how libstdc++ does it
225 ac_test_CFLAGS="${CFLAGS+set}"
226 ac_save_CFLAGS="$CFLAGS"
227
228 # Check for -ffunction-sections -fdata-sections
229 AC_MSG_CHECKING([for gcc that supports -ffunction-sections -fdata-sections])
230 CFLAGS='-Werror -ffunction-sections -fdata-sections'
231 AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
232 if test "$ac_test_CFLAGS" = set; then
233 CFLAGS="$ac_save_CFLAGS"
234 else
235 # this is the suspicious part
236 CFLAGS=""
237 fi
238 if test x"$ac_fdsections" = x"yes"; then
239 SECTION_FLAGS='-ffunction-sections -fdata-sections'
240 fi
241 AC_MSG_RESULT($ac_fdsections)
242 AC_SUBST(SECTION_FLAGS)
243
244
245 # Check for the name of the symbol used for the entry point.
246 AC_CACHE_CHECK([for the name of the symbol used for the entry point],
247 [mudflap_cv_entry_point], [
248 for name in _start __start unknown; do
249 AC_LINK_IFELSE([AC_LANG_PROGRAM([extern char $name@<:@@:>@;], [$name@<:@0@:>@ = 0;])],
250 [break])
251 done
252 mudflap_cv_entry_point="$name"])
253 if test "$mudflap_cv_entry_point" = unknown; then
254 AC_MSG_ERROR([none of the known symbol names works])
255 fi
256 AC_DEFINE_UNQUOTED([ENTRY_POINT], [$mudflap_cv_entry_point],
257 [Define to the name of the symbol used for the entry point.])
258
259
260 if test ${multilib} = yes; then
261 multilib_arg="--enable-multilib"
262 else
263 multilib_arg=
264 fi
265
266 # See if we support thread-local storage.
267 GCC_CHECK_TLS
268 GCC_CHECK_EMUTLS
269
270 AC_CONFIG_FILES([Makefile testsuite/Makefile testsuite/mfconfig.exp])
271 AC_OUTPUT