#!/usr/bin/perl

use strict;
use warnings;
use Getopt::Long;
use File::Path qw/make_path/;
use File::Basename qw/basename dirname/;
use File::Spec qw/rel2abs/;


use FindBin;
use lib "$FindBin::Bin/lib";

use Gears::Interface;
use Gears::Util;


# interface.h
# typedef struct Worker {
#         int id;
#         struct Context* contexts;
#         enum Code execute;
#         enum Code taskSend;
#         enum Code taskRecive;
#         enum Code shutdown;
#         struct Queue* tasks;
#     } Worker;

our($opt_o,$opt_d,$opt_h, $opt_project);

GetOptions(
    "o=s"       => \$opt_o,
    "d=s"       => \$opt_d,
    "h"         => \$opt_h,
    "project=s" => \$opt_project,
);

my $dir = ".";
if ($opt_d) {
    $dir = $opt_d;
    if (! -d $dir) {
        make_path $dir;
    }
}



my %projects = (
    gears => { cotnext => "context" },
    xv6   => { context => "cbc_context" },
);


my $context_name = "context";
if ($opt_project && exists $projects{$opt_project}) {
  $context_name = $projects{$opt_project}->{context};
}



my %var;
my %code;
my %dataGearVar;
my %outputVar;       # output var initializer
my %outputArgs;      # continuation's output variables
my %dataGear;
my %dataGearName;
my %generic;
my %dataGearVarType;
my %codeGear;
my %call_interfaces;
my $interfaceNameToHeaderPath = createInterfaceNameToHeaderPath($FindBin::Bin);
my $searchCbCFromCodeGearAndFilename  = createSearchCbCFileFromCodeGearNameAndFilename($FindBin::Bin);
my %filename2EachCodeGearArgs;
my %specialyEmitStubCodeGears;

my $implInterfaceInfo = {isImpl => undef, implementation => undef, interface => undef};


# this for statement is main routine
for my $fn (@ARGV) {
    next if ($fn !~ /\.cbc$/);
    getDataGear($fn);
    generateDataGear($fn);
}


# interface definision
#
# typedef struct Stack<Type, Impl>{
#         Type* stack;
#         Type* data;
#         Type* data1;
#         __code whenEmpty(...);
#         __code clear(Impl* stack,__code next(...));
#         __code push(Impl* stack,Type* data, __code next(...));
#         __code pop(Impl* stack, __code next(Type*, ...));
#         __code pop2(Impl* stack, Type** data, Type** data1, __code next(Type**, Type**, ...));
#         __code isEmpty(Impl* stack, __code next(...), __code whenEmpty(...));
#         __code get(Impl* stack, Type** data, __code next(...));
#         __code get2(Impl* stack,..., __code next(...));
#         __code next(...);
# } Stack;
#
# calling example
#
# goto nodeStack->push((union Data*)node, stackTest3);
#
# generated meta level code
#
# Gearef(context, Stack)->stack = (union Data*)nodeStack;
# Gearef(context, Stack)->data = (union Data*)node;
# Gearef(context, Stack)->next = C_stackTest3;
# goto meta(context, nodeStack->push);

sub getDataGear {
    my ($filename) = @_;

    my ($codeGearName, $name, $inTypedef,$described_data_gear, $currentCodeGear, $codeGearInfo);
    open my $fd,"<",$filename or die("can't open $filename $!");
    while (<$fd>) {
        if (! $inTypedef) {
          #this scope is usually parsing cbc file
            if (/^typedef struct (\w+)\s*<(.*)>/) {
                $inTypedef = 1;
                $name = $1;
                $dataGear{$name} = $_;
                $var{$name} = {};
                $code{$name} = {};
                $generic{$name} = \split(/,/,$2);
            } elsif (/^typedef struct (\w+)/) {
                $inTypedef = 1;
                $name = $1;
                $dataGear{$name} = $_;
                $var{$name} = {};
                $code{$name} = {};
                $generic{$name} = [];
            } elsif (/^(\w+)(\*)+ create(\w+)\(/) { # this case implementation constructor
                if (defined $implInterfaceInfo->{interface} ) {
                   die "duplicate interface $implInterfaceInfo->{interface}\n";
                }
                my $interfaceName = $1;
                $implInterfaceInfo->{isImpl} = 1;
                $implInterfaceInfo->{interface} = $interfaceName;
                $implInterfaceInfo->{implementation} = $3;
                my $cbc_source_path = $searchCbCFromCodeGearAndFilename->($interfaceName, $filename);
                if ($cbc_source_path) {
                    &getDataGear($cbc_source_path);
                }
            } elsif(/^(.*)par goto (\w+)\((.*)\)/) {
                my $codeGearName = $2;
                my $cbc_source_path = $searchCbCFromCodeGearAndFilename->($codeGearName, $filename);
                if ($cbc_source_path) {
                    &getCodeGear($cbc_source_path);
                }
            } elsif(/^#interface "(.*)"/) {
                # use interface
                my $interfaceHeader = $1;
                next if ($interfaceHeader =~ /context.h/);
                $interfaceHeader =~ m|(\w+)\.\w+$|; #remove filename extention
                my $interfaceName = $1;
                $call_interfaces{$filename}->{$interfaceName} = 1;
                my $interface_path = $interfaceNameToHeaderPath->{$interfaceName};
                if ($interface_path) {
                    &getDataGear($interface_path);
                    &getCodeGear($interface_path);
                }
            } elsif (/^\_\_code (\w+)\((.*)\)(.*)/) {
                my $codeGearName = $1;
                my $args = $2;
                my $cbc_source_path = $searchCbCFromCodeGearAndFilename->($codeGearName, $filename);
                if ($cbc_source_path) {
                    &getCodeGear($cbc_source_path);
                }
                my $vname2type = parseCodeGearDeclarationArg($args);
                for my $vname (keys %$vname2type) {
                  $codeGearInfo->{$codeGearName}->{arg}->{$vname} = $vname2type->{$vname};
                }
                $currentCodeGear = $codeGearName;
            } elsif ((/^\s*(\w+)?\s*(\w+)(\*)\s+(\w+)\s+=/) && $currentCodeGear) { # collect local variables
                my $structType = $1;
                my $interfaceName = $2;
                my $instance = $4;
                $codeGearInfo->{$currentCodeGear}->{localVar}->{$instance} = $interfaceName;
            } elsif (/^(.*)goto (\w+)\-\>(\w+)\((.*)\);/) {
                # handling goto statement
                # convert it to the meta call form with two arugments, that is context and enum Code
                my $prev = $1;
                my $instance = $2;
                my $method = $3;
                my $tmpArgs = $4;
                my $typeName = $codeGearInfo->{$currentCodeGear}->{arg}->{$instance};
                unless ($typeName) {
                  #this case is not __code arguments.
                  for my $localVar (keys %{$codeGearInfo->{$currentCodeGear}->{localVar}}) {
                    if ($localVar eq $instance) {
                      $typeName = $codeGearInfo->{$currentCodeGear}->{localVar}->{$localVar};
                      last;
                    }
                  }
                  unless ($typeName){
                    die "[ERROR] not found $instance type $.: $_\n";
                  }
                }

                my $res = findExistsOutputDataGear($typeName, $method);
                if ($res) {
                   $specialyEmitStubCodeGears{$currentCodeGear} = $res;
                }
            } elsif (/^}$/) {
              $currentCodeGear = undef;
            }
            next;
        }

        #this scope does parsing of header files
        # gather type name and type
        $dataGear{$name} .= $_;
        if (/^\s*(.*)\s+(\w+);$/ ) {
            my $ttype = $1;
            my $tname = $2;
            if ($ttype =~ /^(union|struct|const|enum)\s*(\w+)/) {
                my $structType = $1;
                my $vname = $2;
                if ($structType ne 'const') {
                    $ttype = $vname;
                } else {
                    if ($structType =~ /(const|enum)/) {
                      $ttype = "$structType $vname";
                    }
                }
            }
            $described_data_gear = 1;
            $var{$name}->{$tname} = $ttype;
        }
        if (/__code (\w+)/) {
            next if $described_data_gear;
            my $args = $';
            my $tname2type = parseCodeGearDeclarationArg($args);
            for my $tname (keys %$tname2type) {
              $var{$name}->{$tname} = $tname2type->{$tname};
            }
        }
        if (/^}/) {
            $inTypedef = 0;
        }
    }

    $filename2EachCodeGearArgs{$filename} = $codeGearInfo;

}

sub parseCodeGearDeclarationArg {
    my ($args) = @_;
    my %tname2type;
    while ($args =~ /\s*(struct|union|const|enum)?\s*([\w\[\]_]+)\*?\s*(\w+),?/g) {
      #$args eq  (Impl* vm, pde_t* pgdir, char* init, uint sz, __code next(...));
      my $const_type = $1;
      my $ttype = $2;
      my $tname = $3;

      $ttype =~ s/(Impl|Isa|Type)/Data/;
      if ($const_type && ($const_type =~ /(const|enum)/)) {
        $ttype = "$1 $ttype";
      }
      $tname2type{$tname} = $ttype;
    }
    return \%tname2type;
}

sub getCodeGear {
    my ($filename) = @_;
    open my $fd,"<",$filename or die("can't open $filename $!");
    my ($name,$impln);
    while (<$fd>) {
        if (/^(\w+)\s*(\*)+ create(\w+)\(/) {
            $name = $1;
            $impln = $3;
        } elsif(/^typedef struct (\w+)\s*<.*>\s*{/) {
            $name = $1;
        }
        if (defined $name) {
            if (/^\s*\_\_code (\w+)\((.*)\);/) {
                my $args = $2;
                my $method = $1;
                $code{$name}->{$method} = [];
                while($args) {
                    # replace comma
                    $args =~ s/(^\s*,\s*)//;
                    # continuation case
                    if ($args =~ s/^(\s)*\_\_code\s+(\w+)\(([^)]*)\)//) {
                        my $next = $2;
                        my @args = split(/,/,$3);
                        push(@{$code{$name}->{$method}},"\_\_code $next");
                    } elsif ($args =~ s/^(struct|union|const)?\s*(\w+)(\**)\s+(\w+)//) {
                        my $structType = $1;
                        my $typeName = $2;
                        my $ptrType = $3;
                        my $varName = $4;
                        my $typeField = lcfirst($typeName);
                        if ($structType && ($structType =~ /const/)) {
                            $typeName = "$structType $typeName";
                        }
                        push(@{$code{$name}->{$method}},"$typeName$ptrType $varName");
                    } elsif ($args =~ s/(.*,)//) {
                    } else {
                        last;
                    }
                }
            }
        } elsif (/^\_\_code (\w+)\((.*)\)(.*)/) {
            my $codeGearName = $1;
            my $args = $2;
            my $inputCount = 0;
            my $outputCount = 0;
            my $inputIncFlag = 1;
            while($args) {
                if ($args =~ s/(^\s*,\s*)//) {
                }
                if ($args =~ s/^(\s)*\_\_code\s+(\w+)\((.*?)\)//) {
                    $codeGear{$codeGearName}->{"code"}->{$2} = "\_\_code";
                    $inputIncFlag = 0;
                    my @outputs = split(/,/,$3);
                    for my $output (@outputs) {
                        if ($output =~ /\s*(struct|union|const)?\s*(\w+)(\*)?+\s(\w+)/) {
                            my $structType = $1;
                            my $type = $2;
                            my $varName = $4;
                            if ($structType =~ /const/) {
                                $type = "$structType $type";
                            }
                            $codeGear{$codeGearName}->{"var"}->{$varName} = "$type $outputCount";
                            $outputCount++;
                        }
                    }
                } elsif ($args =~ s/^(struct|union|const)?\s*(\w+)(\*)?+\s(\w+)// && $inputIncFlag) {
                    my $structType = $1;
                    my $type = $2;
                    my $varName = $4;
                    if ($structType =~ /const/) {
                        $type = "$structType $type";
                    }
                    $codeGear{$codeGearName}->{"var"}->{$varName} = "$type $inputCount";
                    $inputCount++;
                } elsif ($args =~ s/(.*,)//) {
                } else {
                    last;
                }
            }
            $codeGear{$codeGearName}->{"input"} = $inputCount;
            $codeGear{$codeGearName}->{"output"} = $outputCount;
        }
    }
}

sub generateStub {
    my($fd,$prevCodeGearName,$dataGearName) = @_;
    print $fd "__code ", $prevCodeGearName ,"_stub(struct Context* $context_name) {\n";
    print $fd $dataGearName;
    print $fd "\n} \n\n";
    return 1;
}

sub generateImplStubArgs {
    my ($codeGearName, $varName, $typeName, $ptrType, $output, $interfaceName, $isImpl) = @_;
    return 0 unless $isImpl;
    for my $ivar (keys %{$var{$interfaceName}}) {
        #  input data gear field
        if ($varName eq $ivar) {
            if ($typeName eq $var{$interfaceName}->{$ivar}) {
                if ($output) {
                    $dataGearName{$codeGearName} .= "\t$typeName$ptrType* O_$varName = &Gearef($context_name, $interfaceName)->$varName;\n";
                    $outputVar{$codeGearName} .= "\t$typeName$ptrType $varName  __attribute__((unused))  = *O_$varName;\n";
                    return 1;
                }
                $dataGearName{$codeGearName} .= "\t$typeName$ptrType $varName = Gearef($context_name, $interfaceName)->$varName;\n";
                return 1;
            }
        }
    }

    # interface continuation
    for my $cName (keys %{$code{$interfaceName}}) {
        if ($varName eq $cName) {
            # continuation field
            $dataGearName{$codeGearName} .= "\tenum Code $varName = Gearef($context_name, $interfaceName)->$varName;\n";
            return 1;
        }
    }
}

sub generateStubArgs {
    my($codeGearName, $varName, $typeName, $ptrType, $typeField, $implInterfaceInfo,$output) = @_;

    my $isImpl = $implInterfaceInfo->{isImpl};
    my $interfaceName = $implInterfaceInfo->{interface};
    my $implName = $implInterfaceInfo->{implementation};

    my $varname1 = $output ? "O_$varName" : $varName;
    for my $n ( @{$dataGearVar{$codeGearName}} ) {
        # we already have it
        return 0 if ( $n eq $varname1);
    }
    push @{$dataGearVar{$codeGearName}}, $varname1;
    push @{$dataGearVarType{$codeGearName}}, $typeName;

    if ($isImpl){
        if ($implName eq $typeName) {
          # get implementation
          $dataGearName{$codeGearName} .= "\t$typeName* $varName = ($typeName*)GearImpl($context_name, $interfaceName, $varName);\n";
          return 1;
        }
    }

    return 1 if generateImplStubArgs($codeGearName, $varName, $typeName, $ptrType, $output, $interfaceName, $isImpl);

    # par goto  var
    for my $var (keys %{$codeGear{$codeGearName}->{"var"}}) {
        #  input data gear field
        if ($varName eq $var) {
            my ($type, $count) = split(/\s/, $codeGear{$codeGearName}->{"var"}->{$var});
            if ($typeName eq $type) {
                if ($output) {
                    $dataGearName{$codeGearName} .= "\t$typeName$ptrType* O_$varName = ($typeName $ptrType*)&${context_name}->data[${context_name}\->odg + $count];\n";
                    $outputVar{$codeGearName} .= "\t$typeName$ptrType $varName = *O_$varName;\n";
                    return 1;
                }
                $dataGearName{$codeGearName} .= "\t$typeName$ptrType $varName = &${context_name}->data[${context_name}\->idg + $count]->$typeName;\n";
                return 1;
            }
        }
    }

    # par goto continuation
    for my $cName (keys %{$codeGear{$codeGearName}->{"code"}}) {
        if ($varName eq $cName) {
            # continuation field
            $dataGearName{$codeGearName} .= "\tenum Code $varName = ${context_name}\->next;\n";
            return 1;
        }
    }


    # par goto continuation
    # global or local variable case
    if (($typeName eq "Code") && $isImpl) {
        $dataGearName{$codeGearName} .= "\tenum $typeName$ptrType $varName = Gearef(${context_name}, $interfaceName)->$varName;\n";
        return 1;
    }
    $dataGearName{$codeGearName} .= "\t$typeName$ptrType $varName = Gearef($context_name, $typeName);\n";
    return 1;
}



sub findExistsOutputDataGear {
    my ($interfaceName, $method) = @_;

    my $interfacePATH = $interfaceNameToHeaderPath->{$interfaceName};
    unless ($interfacePATH) {
      return undef;
    }

    my $parsedInterface = Gears::Interface->separate_code_and_data_gear_after_parse($interfacePATH);

    unless ($parsedInterface) {
      return undef;
    }

    unless (exists $parsedInterface->{hasOutputArgs}->{$method}) {
      return undef;
    }

    my $vname2types = $parsedInterface->{hasOutputArgs}->{$method};

    my @outputArgs = keys %$vname2types;
    return \@outputArgs;
}


sub generateDataGear {
    my ($filename) = @_;
    open my $in,"<",$filename or die("can't open $filename $!");

    my $fn;
    if ($opt_o) {
        $fn = $opt_o;
    } else {
        my $fn1 = $filename;
        $fn1 =~ s/\.cbc/.c/;
        my $i = 1;
        $fn = "$dir/$fn1";
        while ( -f $fn) {
            $fn = "$dir/$fn1.$i";
            $i++;
        }
    }
    if ( $fn =~ m=(.*)/[^/]+$= ) {
        if (! -d $1) {
            make_path $1;
        }
    }
    open my $fd,">",$fn or die("can't write $fn $!");

    my $prevCodeGearName;
    my $inTypedef = 0;
    my $inStub = 0;
    my $hasParGoto = 0;
    my $inMain = 0 ;
    my $inCode = 0 ;
    my %stub;
    my $codeGearName;
    my %localVarType;

    while (<$in>) {
        if (! $inTypedef && ! $inStub && ! $inMain) {
            if (/^typedef struct (\w+)\s*\{/) {
                $inTypedef = 1;
            } elsif (/^int main\((.*)\) \{/) {
                $inMain = 1;
            } elsif(/^#interface "(.*)"/) {
                my $interfaceHeader = $1;
                # #interface not write
                next unless ($interfaceHeader =~ /context.h/);
            } elsif (/^\_\_code (\w+)\((.*)\)(.*)/) {
                $inCode = 1;
                %localVarType = ();
                $codeGearName = $1;
                my $args = $2;
                my $tail = $3;
                if ($codeGearName =~ /_stub$/) {
                    # don't touch already existing stub
                    $inStub = 1;
                    $stub{$codeGearName} = 1;
                    print $fd $_;
                    next;
                }
                if (defined $prevCodeGearName) {
                    # stub is generated just before next CodeGear
                    if (defined $stub{$prevCodeGearName."_stub"}) {
                        undef $prevCodeGearName;
                    } else {
                        &generateStub($fd,$prevCodeGearName,$dataGearName{$prevCodeGearName});
                        $stub{$prevCodeGearName."_stub"} = 1;
                    }
                }
                # analyzing CodeGear argument
                #      these arguments are extract from current context's arugment DataGear Interface
                #      and passed to the CodeGear
                #      struct Implementaion needs special handling
                #      __code next(...)   --->   enum Code next
                $prevCodeGearName = $codeGearName;
                $dataGearVar{$codeGearName} = [];
                $outputVar{$codeGearName} = "";
                $outputArgs{$codeGearName} = {};
                my $newArgs = "struct Context *${context_name},";
                if ($args=~/^struct Context\s*\*\s*${context_name}/) {
                    $newArgs = "";
                }
                if (!$args){
                    $newArgs = "struct Context *${context_name}";
                }
                while($args) {
                    if ($args =~ s/(^\s*,\s*)//) {
                        $newArgs .= $1;
                    }
                    # continuation case
                    if ($args =~ s/^(\s)*\_\_code\s+(\w+)\(([^)]*)\)//) {
                        my $next = $2;
                        my @args = split(/,/,$3);
                        if (generateStubArgs($codeGearName, $next, "Code", "", $next, $implInterfaceInfo,0) ) {
                            $newArgs .= "enum Code $next";
                        }
                        # analyze continuation arguments
                        #    output arguments are defined in the Interface take the pointer of these
                        #    output arguments are put into the Interface DataGear just before the goto
                        for my $arg (@args) {
                            $arg =~ s/^\s*//;
                            last if ($arg =~ /\.\.\./);
                            $arg =~ s/^(struct|union|const|enum)?\s*(\w+)(\**)\s(\w+)//;
                            my $structType = $1;
                            my $typeName = $2;
                            my $ptrType = $3;
                            my $varName = $4;
                        if ($structType =~ /(const|enum)/) {
                            $typeName = "$structType $typeName";
                        }
                            my $typeField = lcfirst($typeName);
                            push(@{$outputArgs{$codeGearName}->{$next}}, $varName);
                            if (generateStubArgs($codeGearName, $varName, $typeName, $ptrType, $typeField, $implInterfaceInfo,1)) {
                                $newArgs .= ",$structType $typeName **O_$varName";
                            }
                        }
                    } elsif ($args =~ s/^(struct|union|const|enum)?\s*(\w+)(\**)\s(\w+)//) {
                        my $structType = $1;
                        my $typeName = $2;
                        my $ptrType = $3;
                        my $varName = $4;
                        $newArgs .= $&;    # assuming no duplicate
                        if ($structType && ($structType =~ /(const|enum)/)) {
                            $typeName = "$structType $typeName";
                        }
                        my $typeField = lcfirst($typeName);
                        generateStubArgs($codeGearName, $varName, $typeName, $ptrType, $typeField, $implInterfaceInfo,0);
                    } elsif ($args =~ s/(.*,)//) {
                        $newArgs .= $1;
                    } else {
                        $newArgs .= $args;
                        last;
                    }
                }
                # generate goto statement from stub to the CodeGear in the buffer
                $dataGearName{$codeGearName} .= "\tgoto $codeGearName(${context_name}";
                for my $arg ( @{$dataGearVar{$codeGearName}}) {
                    $dataGearName{$codeGearName} .= ", $arg";
                }
                $dataGearName{$codeGearName} .= ");";
                # generate CodeGear header with new arguments
                print $fd "__code $codeGearName($newArgs)$tail\n";
                if ($outputVar{$codeGearName} ne "") {
                    # output data var can be use before write
                    # it should be initialze by gearef
                    print $fd $outputVar{$codeGearName};
                }
                next;
            } elsif (! $inCode) {
                s/new\s+(\w+)\(\)/\&ALLOCATE(${context_name}, $1)->$1/g;   # replacing new
                print $fd $_;
                next;
            } elsif (/^(.*)goto (\w+)\-\>(\w+)\((.*)\);/) {
                # handling goto statement
                # convert it to the meta call form with two arugments, that is context and enum Code
                my $prev = $1;
                my $next = $2;
                my $method = $3;
                my $tmpArgs = $4;
                #$tmpArgs =~ s/\(.*\)/\(\)/;
                my @args = split(/,/,$tmpArgs);
                if (! defined $dataGearVarType{$codeGearName}) {
                   print $fd $_ ;
                   next ;
                }
                my @types = @{$dataGearVarType{$codeGearName}};
                my $ntype;
                my $ftype;
                for my $v (@{$dataGearVar{$codeGearName}}) {
                    my $t = shift @types;
                    if ($v eq $next || $v eq "O_$next") {
                        $ntype = $t;
                        $ftype = lcfirst($ntype);
                    }
                }
                if (!defined $ntype) {
                    $ntype = $localVarType{$next};
                    $ftype = lcfirst($ntype);
                }
                print $fd "\tGearef(${context_name}, $ntype)->$ftype = (union Data*) $next;\n";
                # Put interface argument
                my $prot = $code{$ntype}->{$method};
                my $i = 1;
                for my $arg (@args) {
                    my $pType;
                    my $pName;
                    my $p = @$prot[$i];
                    next if ($p eq $arg);
                    $p =~ s/^(.*)\s(\w+)//;
                    $pType = $1;
                    $pName = $2;
                    $arg =~ s/^(\s)*(\w+)/$2/;
                    if ($pType =~ s/\_\_code$//) {
                        if ($arg =~ /(\w+)\(.*\)/) {
                            print $fd "\tGearef(${context_name}, $ntype)->$pName = $1;\n";
                        } else {
                            print $fd "\tGearef(${context_name}, $ntype)->$pName = C_$arg;\n";
                        }
                    } elsif ($pType =~ /Data\**$/){
                        print $fd "\tGearef(${context_name}, $ntype)->$pName = (union $pType) $arg;\n";
                    } else {
                        print $fd "\tGearef(${context_name}, $ntype)->$pName = $arg;\n";
                    }
                    $i++;
                }
                print $fd "${prev}${context_name}->before = C_$codeGearName;\n";
                print $fd "${prev}goto meta(${context_name}, $next->$method);\n";
                next;
            } elsif(/^(.*)par goto (\w+)\((.*)\);/) {
                # handling par goto statement
                # convert it to the parallel
                my $prev = $1;
                my $codeGearName = $2;
                my $args = $3;
                my $inputCount = $codeGear{$codeGearName}->{'input'};
                my $outputCount = $codeGear{$codeGearName}->{'output'};
                my @iterateCounts;
                # parse examples 'par goto(.., iterate(10), exit);'
                if ($args =~ /iterate\((.*)?\),/) {
                    @iterateCounts = split(/,/,$1);;
                    $inputCount--;
                }
                # replace iterate keyword
                $args =~ s/iterate\((.*)?\),//;
                my @dataGears = split(/,\s*/, $args);
                my $nextCodeGear = pop(@dataGears);
                if (! $hasParGoto) {
                    $hasParGoto = 1;
                    print $fd "${prev}struct Element* element;\n";
                }
                my $initTask = << "EOFEOF";
                ${prev}${context_name}\->task = NEW(struct Context);
                ${prev}initContext(${context_name}\->task);
                ${prev}${context_name}\->task->next = C_$codeGearName;
                ${prev}${context_name}\->task->idgCount = $inputCount;
                ${prev}${context_name}\->task->idg = ${context_name}\->task->dataNum;
                ${prev}${context_name}\->task->maxIdg = ${context_name}\->task->idg + $inputCount;
                ${prev}${context_name}\->task->odg = ${context_name}\->task->maxIdg;
                ${prev}${context_name}\->task->maxOdg = ${context_name}\->task->odg + $outputCount;
EOFEOF
                print $fd $initTask;
                if (@iterateCounts) {
                    print $fd "${prev}${context_name}\->task->iterate = 0;\n";
                    my $len = @iterateCounts;
                    if ($len == 1) {
                        print $fd "${prev}${context_name}\->task->iterator = createMultiDimIterator(${context_name}, $iterateCounts[0], 1, 1);\n";
                    } elsif ($len == 2) {
                        print $fd "${prev}${context_name}\->task->iterator = createMultiDimIterator(${context_name}, $iterateCounts[0], $iterateCounts[1], 1);\n";
                    } elsif ($len == 3) {
                        print $fd "${prev}${context_name}\->task->iterator = createMultiDimIterator(${context_name}, $iterateCounts[0], $iterateCounts[1], $iterateCounts[2]);\n";
                    }
                }
                for my $dataGear (@dataGears) {
                    print $fd "${prev}GET_META($dataGear)->wait = createSynchronizedQueue(${context_name});\n";
                }
                for my $i (0..$inputCount-1) {
                    print $fd "${prev}${context_name}\->task->data[${context_name}\->task->idg+$i] = (union Data*)$dataGears[$i];\n";
                }
                for my $i (0..$outputCount-1) {
                    print $fd "${prev}${context_name}\->task->data[${context_name}\->task->odg+$i] = (union Data*)$dataGears[$inputCount+$i];\n";
                }
                my $putTask = << "EOFEOF";
                ${prev}element = &ALLOCATE(${context_name}, Element)->Element;
                ${prev}element->data = (union Data*)${context_name}\->task;
                ${prev}element->next = ${context_name}\->taskList;
                ${prev}${context_name}\->taskList = element;
EOFEOF
                print $fd $putTask;
                next;
            } elsif (/^(.*)goto (\w+)\((.*)\);/) {
                # handling goto statement
                # convert it to the meta call form with two arugments, that is context and enum Code
                my $prev = $1;
                my $next = $2;
                my @args = split(/,/, $3);
                my $v = 0;
                my $arg_context = $context_name;
                if ($prev =~ /kernel/) {
                  $prev = "";
                  $arg_context = "kernel";
                }

                for my $n ( @{$dataGearVar{$codeGearName}} ) {
                    # continuation arguments
                    $v = 1  if ( $n eq $next);
                }
                if ($v || ($implInterfaceInfo->{isImpl} && defined $code{$implInterfaceInfo->{interface}}->{$next})) {
                    # write continuation's arguments into the interface arguments
                    # we may need a commit for a shared DataGear
                    for my $arg ( @{$outputArgs{$codeGearName}->{$next}} ) {
                        my $v = shift(@args);
                        print $fd "\t*O_$arg = $v;\n";
                    }
                    if ($hasParGoto) {
                        print $fd "${prev}Gearef(${arg_context}, TaskManager)->taskList = ${arg_context}->taskList;\n";
                        print $fd "${prev}Gearef(${arg_context}, TaskManager)->next1 = C_$next;\n";
                        print $fd "${prev}goto meta(${arg_context}, C_$next);\n";
                    } else {
                        print $fd "${prev}${arg_context}->before = C_$codeGearName;\n";
                        print $fd "${prev}goto meta(${arg_context}, $next);\n";
                    }
                    next;
                }
                if ($hasParGoto) {
                    print $fd "${prev}Gearef(${arg_context}, TaskManager)->taskList = ${arg_context}\->taskList;\n";
                    print $fd "${prev}Gearef(${arg_context}, TaskManager)->next1 = C_$next;\n";
                    print $fd "${prev}goto parGotoMeta(${arg_context}, C_$next);\n";
                    next;
                } elsif ($next eq "meta") {
                    print $fd $_;
                    next;
                } else {
                    print $fd "${prev}${arg_context}\->before = C_$codeGearName;\n";
                    print $fd "${prev}goto meta(${arg_context}, C_$next);\n";
                    next;
                }
            } elsif(/^.*(struct|union)?\s(\w+)\*\s(\w+)\s?[=;]/) {
                my $type    = $2;
                my $varName = $3;
                $localVarType{$varName} = $type;
                s/new\s+(\w+)\(\)/\&ALLOCATE(${context_name}, $1)->$1/g;   # replacing new
            } elsif(/^}/) {
                $hasParGoto = 0;
            } else {
                s/new\s+(\w+)\(\)/\&ALLOCATE(${context_name}, $1)->$1/g;   # replacing new
            }
            # gather type name and type
        } elsif ($inMain) {
            if (/^(.*)goto start_code\(main_${context_name}\);/) {
                print $fd $_;
                next;
            } elsif (/^(.*)goto (\w+)\((.*)\);/) {
                my $prev = $1;
                my $next = $2;
                print $fd "${prev}struct Context* main_${context_name} = NEW(struct Context);\n";
                print $fd "${prev}initContext(main_${context_name});\n";
                print $fd "${prev}main_${context_name}->next = C_$next;\n";
                print $fd "${prev}goto start_code(main_${context_name});\n";
                next;
            }
        }
        if (/^}/) {
            $inStub = 0;
            $inTypedef = 0;
            $inMain = 0;
            $inCode = 0;
        }
        print $fd $_;
    }
    if (defined $prevCodeGearName) {
        if (!defined $stub{$prevCodeGearName."_stub"}) {
            $stub{$prevCodeGearName."_stub"} = &generateStub($fd,$prevCodeGearName,$dataGearName{$codeGearName});
        }
    }

}

sub createInterfaceNameToHeaderPath {
    my $search_root = shift;
    my $files = Gears::Util->find_headers_from_path($search_root);
    my $interface_name2headerpath = {};

    for my $file (@{$files}) {
      if ($file =~ m|/(\w+)\.\w+$|) {
        my $file_name = $1;
        $interface_name2headerpath->{$file_name} = $file;
      }
    }

    return $interface_name2headerpath;
}

sub create_cbc_name_to_source_path {
  # create this structure
  #
  # {
  #    SemaphoreImpl.cbc           [
  #      [0] "/Users/anatofuz/src/firefly/hg/Gears/Gears/src/parallel_execution/SemaphoreImpl.cbc",
  #      [1] "/Users/anatofuz/src/firefly/hg/Gears/Gears/src/parallel_execution/examples/boundedBuffer/SemaphoreImpl.cbc"
  #  ],
  #  SingleLinkedQueue.cbc       [
  #      [0] "/Users/anatofuz/src/firefly/hg/Gears/Gears/src/parallel_execution/SingleLinkedQueue.cbc"
  #  ],
  # }
  my $search_root = shift;
  my $files = Gears::Util->find_cbc_sources_from_path($search_root);

  my $cbc_name2_source_path = {};
  for my $file (@{$files}) {
    my $cbc_name = basename $file;
    $cbc_name =~ s/\.cbc//;
    push(@{$cbc_name2_source_path->{$cbc_name}},$file);
  }
  return $cbc_name2_source_path;
}

sub createSearchCbCFileFromCodeGearNameAndFilename {
  my $search_root = shift;
  my $cbc_name2_source_path = create_cbc_name_to_source_path($search_root);

  # return sub is create clojure
  return sub {
    my ($codeGearName, $filename) = @_;
    my $cbc_files = $cbc_name2_source_path->{$codeGearName} // [];

    if (scalar(@{$cbc_files}) == 0) { # Not Found
      return 0; #false case
    }

    if (scalar(@{$cbc_files}) == 1) { # this case  $codeGearName.cbc is single (SingleLinkedQueue.cbc)
      return $cbc_files->[0];     # return "/Users/anatofuz/src/firefly/hg/Gears/Gears/src/parallel_execution/SingleLinkedQueue.cbc"
    }


    my $cbc_dir_name = dirname $filename;

    for my $cbc_file (@{$cbc_files}) {
      if ($cbc_file =~ /$cbc_dir_name/) {
        return $cbc_file;
      }
    }

    return 0; # Not found
  }
}