open import Level
module constructible-set (n : Level) where

open import zf

open import Data.Nat renaming ( zero to Zero ; suc to Suc ;  ℕ to Nat ) 

open import  Relation.Binary.PropositionalEquality

data OrdinalD  : (lv : Nat) → Set n where
   Φ : {lv : Nat} → OrdinalD  lv
   OSuc : {lv : Nat} → OrdinalD  lv → OrdinalD lv
   ℵ_ :  (lv : Nat) → OrdinalD (Suc lv)

record Ordinal : Set n where
   field
     lv : Nat
     ord : OrdinalD lv

data _d<_  :  {lx ly : Nat} → OrdinalD  lx  →  OrdinalD  ly  → Set n where
   Φ<  : {lx : Nat} → {x : OrdinalD  lx}  →  Φ  {lx} d< OSuc  {lx} x
   s<  : {lx : Nat} → {x y : OrdinalD  lx}  →  x d< y  → OSuc  {lx} x d< OSuc  {lx} y
   ℵΦ< : {lx : Nat} → {x : OrdinalD  (Suc lx) } →  Φ  {Suc lx} d< (ℵ lx) 
   ℵ<  : {lx : Nat} → {x : OrdinalD  (Suc lx) } →  OSuc  {Suc lx} x d< (ℵ lx) 

open Ordinal

_o<_ : ( x y : Ordinal ) → Set n
_o<_ x y =  (lv x < lv y )  ∨ ( ord x d< ord y )

open import Data.Nat.Properties 
open import Data.Empty
open import Relation.Nullary

open import Relation.Binary
open import Relation.Binary.Core

≡→¬d< : {lv : Nat} → {x  : OrdinalD  lv }  → x d< x → ⊥
≡→¬d<  {lx} {OSuc y} (s< t) = ≡→¬d< t

trio<> : {lx : Nat} {x  : OrdinalD  lx } { y : OrdinalD  lx }  →  y d< x → x d< y → ⊥
trio<>  {lx} {.(OSuc _)} {.(OSuc _)} (s< s) (s< t) = 
    trio<> s t

trio<≡ : {lx : Nat} {x  : OrdinalD  lx } { y : OrdinalD  lx }  → x ≡ y  → x d< y → ⊥
trio<≡ refl = ≡→¬d<

trio>≡ : {lx : Nat} {x  : OrdinalD  lx } { y : OrdinalD  lx }  → x ≡ y  → y d< x → ⊥
trio>≡ refl = ≡→¬d<

triO : {lx ly : Nat} → OrdinalD  lx  →  OrdinalD  ly  → Tri (lx < ly) ( lx ≡ ly ) ( lx > ly )
triO  {lx} {ly} x y = <-cmp lx ly

triOrdd : {lx : Nat}   → Trichotomous  _≡_ ( _d<_  {lx} {lx} )
triOrdd  {lv} Φ Φ = tri≈ ≡→¬d< refl ≡→¬d<
triOrdd  {Suc lv} (ℵ lv) (ℵ lv) = tri≈ ≡→¬d< refl ≡→¬d<
triOrdd  {lv} Φ (OSuc y) = tri< Φ< (λ ()) ( λ lt → trio<> lt Φ< )
triOrdd  {.(Suc lv)} Φ (ℵ lv) = tri<  (ℵΦ<  {lv} {Φ} ) (λ ()) ( λ lt → trio<> lt ((ℵΦ<  {lv} {Φ} )) )
triOrdd  {Suc lv} (ℵ lv) Φ = tri> ( λ lt → trio<> lt (ℵΦ<  {lv} {Φ} ) ) (λ ()) (ℵΦ<  {lv} {Φ} )
triOrdd  {Suc lv} (ℵ lv) (OSuc y) = tri> ( λ lt → trio<> lt (ℵ<  {lv} {y} )  ) (λ ()) (ℵ<  {lv} {y} )
triOrdd  {lv} (OSuc x) Φ = tri> (λ lt → trio<> lt Φ<) (λ ()) Φ<
triOrdd  {.(Suc lv)} (OSuc x) (ℵ lv) = tri< ℵ< (λ ()) (λ lt → trio<> lt ℵ< )
triOrdd  {lv} (OSuc x) (OSuc y) with triOrdd x y
triOrdd  {lv} (OSuc x) (OSuc y) | tri< a ¬b ¬c = tri< (s< a) (λ tx=ty → trio<≡ tx=ty (s< a) )  (  λ lt → trio<> lt (s< a) )
triOrdd  {lv} (OSuc x) (OSuc x) | tri≈ ¬a refl ¬c = tri≈ ≡→¬d< refl ≡→¬d<
triOrdd  {lv} (OSuc x) (OSuc y) | tri> ¬a ¬b c = tri> (  λ lt → trio<> lt (s< c) ) (λ tx=ty → trio>≡ tx=ty (s< c) ) (s< c)

d<→lv :  {x y  : Ordinal }   → ord x d< ord y → lv x ≡ lv y
d<→lv Φ< = refl
d<→lv (s< lt) = refl
d<→lv ℵΦ< = refl
d<→lv ℵ< = refl

orddtrans : {lx : Nat} {x y z : OrdinalD  lx }   → x d< y → y d< z → x d< z
orddtrans {lx} {.Φ} {.(OSuc _)} {.(OSuc _)} Φ< (s< y<z) = Φ< 
orddtrans {Suc lx} {Φ {Suc lx}} {OSuc y} {ℵ lx} Φ< ℵ< = ℵΦ< {lx} {y}
orddtrans {lx} {.(OSuc _)} {.(OSuc _)} {.(OSuc _)} (s< x<y) (s< y<z) = s< ( orddtrans x<y y<z )
orddtrans {.(Suc _)} {.(OSuc _)} {.(OSuc _)} {.(ℵ _)} (s< x<y) ℵ< = ℵ<
orddtrans {.(Suc _)} {.Φ} {.(ℵ _)} {z} ℵΦ< ()
orddtrans {.(Suc _)} {.(OSuc _)} {.(ℵ _)} {z} ℵ< ()

max : (x y : Nat) → Nat
max Zero Zero = Zero
max Zero (Suc x) = (Suc x)
max (Suc x) Zero = (Suc x)
max (Suc x) (Suc y) = Suc ( max x y )

maxαd : { lx : Nat } → OrdinalD  lx  →  OrdinalD  lx  →  OrdinalD  lx
maxαd x y with triOrdd x y
maxαd x y | tri< a ¬b ¬c = y
maxαd x y | tri≈ ¬a b ¬c = x
maxαd x y | tri> ¬a ¬b c = x

maxα :  Ordinal →  Ordinal  → Ordinal
maxα x y with <-cmp (lv x) (lv y)
maxα x y | tri< a ¬b ¬c = x
maxα x y | tri> ¬a ¬b c = y
maxα x y | tri≈ ¬a refl ¬c = record { lv = lv x ; ord = maxαd (ord x) (ord y) }

OrdTrans : Transitive (λ ( a b : Ordinal ) → (a ≡ b) ∨ (Ordinal.lv a < Ordinal.lv b) ∨ (Ordinal.ord a d< Ordinal.ord b) )
OrdTrans (case1 refl) (case1 refl) = case1 refl
OrdTrans (case1 refl) (case2 lt2) = case2 lt2
OrdTrans (case2 lt1) (case1 refl) = case2 lt1
OrdTrans (case2 (case1 x)) (case2 (case1 y)) = case2 (case1 ( <-trans x y ) )
OrdTrans (case2 (case1 x)) (case2 (case2 y)) with d<→lv y
OrdTrans (case2 (case1 x)) (case2 (case2 y)) | refl = case2 (case1 x )
OrdTrans (case2 (case2 x)) (case2 (case1 y)) with d<→lv x
OrdTrans (case2 (case2 x)) (case2 (case1 y)) | refl = case2 (case1 y)
OrdTrans (case2 (case2 x)) (case2 (case2 y)) with d<→lv x | d<→lv y
OrdTrans (case2 (case2 x)) (case2 (case2 y)) | refl | refl = case2 (case2 (orddtrans x y ))

OrdPreorder : Preorder n n n
OrdPreorder = record { Carrier = Ordinal
   ; _≈_  = _≡_ 
   ; _∼_   = λ a b → (a ≡ b)  ∨ ( a o< b )  
   ; isPreorder   = record {
        isEquivalence = record { refl = refl  ; sym = sym ; trans = trans }
        ; reflexive     = case1 
        ; trans         = OrdTrans
     }
 }

-- X' = { x ∈ X |  ψ  x } ∪ X , Mα = ( ∪ (β < α) Mβ ) '

data Constructible ( α : Ordinal  )  :  Set (suc n) where
    fsub : ( ψ : Ordinal  → Set n ) → Constructible  α
    xself : Ordinal → Constructible  α

record ConstructibleSet  : Set (suc n) where
  field
    α : Ordinal
    constructible : Constructible α

open ConstructibleSet

data _c∋_  : {α α' : Ordinal  }  →
        Constructible  α → Constructible   α' → Set n where
    c> :  {α α' : Ordinal }
        (ta : Constructible  α ) ( tx : Constructible   α' ) → α' o< α →  ta c∋ tx
    xself-fsub  :  {α : Ordinal  } 
         (ta : Ordinal ) ( ψ : Ordinal  → Set n ) → _c∋_  {α} {α} (xself ta ) ( fsub ψ)  
    fsub-fsub :  {α : Ordinal   } 
          ( ψ : Ordinal   → Set n ) ( ψ₁ : Ordinal   → Set n ) →
         ( ∀ ( x :  Ordinal  ) → ψ x →  ψ₁ x ) →  _c∋_  {α} {α} ( fsub ψ ) ( fsub ψ₁) 

_∋_  : (ConstructibleSet ) → (ConstructibleSet  ) → Set n 
a ∋ x  = constructible a c∋ constructible x

-- transitiveness : (a b c : ConstructibleSet ) → a ∋ b → b ∋ c → a ∋ c
-- transitiveness  a b c a∋b b∋c with constructible a c∋ constructible b | constructible b c∋ constructible c
-- ... | t1 | t2 = {!!}

data _c≈_  :  {α α' : Ordinal}  →
        Constructible  α → Constructible   α' → Set n where
    crefl :  {α : Ordinal  } → _c≈_  {α} {α} (xself α ) (xself α )
    feq :  {lv : Nat} {α : Ordinal }
          → ( ψ : Ordinal  → Set n ) ( ψ₁ : Ordinal → Set n ) 
          → (∀ ( x :  Ordinal ) → ψ x  ⇔ ψ₁ x ) → _c≈_    {α} {α} ( fsub ψ ) ( fsub ψ₁)

_≈_  : (ConstructibleSet ) → (ConstructibleSet  ) → Set n 
a ≈ x  = constructible a c≈ constructible x

ConstructibleSet→ZF : ZF {suc n} 
ConstructibleSet→ZF   = record { 
    ZFSet = ConstructibleSet 
    ; _∋_ = _∋_
    ; _≈_ = _≈_ 
    ; ∅  = record {  α = record {lv = Zero ; ord = Φ } ; constructible = xself ( record {lv = Zero ; ord = Φ }) }
    ; _×_ = {!!}
    ; Union = {!!}
    ; Power = {!!}
    ; Select = {!!}
    ; Replace = {!!}
    ; infinite = {!!}
    ; isZF = {!!}
 }