open import Level
module ordinal-definable where

open import zf
open import ordinal

open import Data.Nat renaming ( zero to Zero ; suc to Suc ;  ℕ to Nat ; _⊔_ to _n⊔_ ) 

open import  Relation.Binary.PropositionalEquality

open import Data.Nat.Properties 
open import Data.Empty
open import Relation.Nullary

open import Relation.Binary
open import Relation.Binary.Core

-- Ordinal Definable Set

record OD {n : Level}  : Set (suc n) where
  field
    def : (x : Ordinal {n} ) → Set n

open OD
open import Data.Unit

open Ordinal

postulate      
  od→ord : {n : Level} → OD {n} → Ordinal {n}
  ord→od : {n : Level} → Ordinal {n} → OD {n} 

_∋_ : { n : Level } → ( a x : OD {n} ) → Set n
_∋_ {n} a x  = def a ( od→ord x )

_c<_ : { n : Level } → ( a x : OD {n} ) → Set n
x c< a = a ∋ x 

record _==_ {n : Level} ( a b :  OD {n} ) : Set n where
  field
     eq→ : ∀ { x : Ordinal {n} } → def a x → def b x 
     eq← : ∀ { x : Ordinal {n} } → def b x → def a x 

id : {n : Level} {A : Set n} → A → A
id x = x

eq-refl : {n : Level} {  x :  OD {n} } → x == x
eq-refl {n} {x} = record { eq→ = id ; eq← = id }

open  _==_ 

eq-sym : {n : Level} {  x y :  OD {n} } → x == y → y == x
eq-sym eq = record { eq→ = eq← eq ; eq← = eq→ eq }

eq-trans : {n : Level} {  x y z :  OD {n} } → x == y → y == z → x == z
eq-trans x=y y=z = record { eq→ = λ t → eq→ y=z ( eq→ x=y  t) ; eq← = λ t → eq← x=y ( eq← y=z t) }

_c≤_ : {n : Level} →  OD {n} →  OD {n} → Set (suc n)
a c≤ b  = (a ≡ b)  ∨ ( b ∋ a )

od∅ : {n : Level} → OD {n} 
od∅ {n} = record { def = λ _ → Lift n ⊥ }

postulate      
  c<→o< : {n : Level} {x y : OD {n} } → x c< y → od→ord x o< od→ord y
  o<→c< : {n : Level} {x y : Ordinal {n} } → x o< y → ord→od x c< ord→od y
  oiso : {n : Level} {x : OD {n}} → ord→od ( od→ord x ) ≡ x
  diso : {n : Level} {x : Ordinal {n}} → od→ord ( ord→od x ) ≡ x
  sup-od : {n : Level } → ( OD {n} → OD {n}) →  OD {n}
  sup-c< : {n : Level } → ( ψ : OD {n} →  OD {n}) → ∀ {x : OD {n}} → ψ x  c< sup-od ψ
  ∅-base-def : {n : Level} → def ( ord→od (o∅ {n}) ) ≡ def (od∅ {n})

congf : {n : Level} {x y : OD {n}} → { f g : OD {n} → OD {n} } → x ≡ y → f ≡ g → f x ≡ g y 
congf refl refl = refl

o∅→od∅ : {n : Level} → ord→od (o∅ {n}) ≡ od∅ {n}
o∅→od∅ {n} = cong ( λ k → record { def = k }) ( ∅-base-def ) 

∅1 : {n : Level} →  ( x : OD {n} )  → ¬ ( x c< od∅ {n} )
∅1 {n} x (lift ())

∅3 : {n : Level} →  { x : Ordinal {n}}  → ( ∀(y : Ordinal {n}) → ¬ (y o< x ) ) → x ≡ o∅ {n}
∅3 {n} {x} = TransFinite {n} c1 c2 c3 x where
   c0 : Nat →  Ordinal {n}  → Set n
   c0 lx x = (∀(y : Ordinal {n}) → ¬ (y o< x))  → x ≡ o∅ {n}
   c1 : ∀ (lx : Nat ) →  c0 lx (record { lv = Suc lx ; ord = ℵ lx } )  
   c1 lx not with not ( record { lv = lx ; ord = Φ lx } )
   ... | t with t (case1 ≤-refl )
   c1 lx not | t | ()
   c2 : (lx : Nat) → c0 lx (record { lv = lx ; ord = Φ lx } )
   c2 Zero not = refl
   c2 (Suc lx) not with not ( record { lv = lx ; ord = Φ lx } )
   ... | t with t (case1 ≤-refl )
   c2 (Suc lx) not | t | ()
   c3 : (lx : Nat) (x₁ : OrdinalD lx) → c0 lx  (record { lv = lx ; ord = x₁ })  → c0 lx (record { lv = lx ; ord = OSuc lx x₁ })
   c3 lx (Φ .lx) d not with not ( record { lv = lx ; ord = Φ lx } )
   ... | t with t (case2 Φ< )
   c3 lx (Φ .lx) d not | t | ()
   c3 lx (OSuc .lx x₁) d not with not (  record { lv = lx ; ord = OSuc lx x₁ } )
   ... | t with t (case2 (s< s<refl ) )
   c3 lx (OSuc .lx x₁) d not | t | ()
   c3 (Suc lx) (ℵ lx) d not with not ( record { lv = Suc lx ; ord = OSuc (Suc lx) (Φ (Suc lx)) }  )
   ... | t with t (case2 (s< ℵΦ<   )) 
   c3 .(Suc lx) (ℵ lx) d not | t | ()

def-subst : {n : Level } {Z : OD {n}} {X : Ordinal {n} }{z : OD {n}} {x : Ordinal {n} }→ def Z X → Z ≡ z  →  X ≡ x  →  def z x
def-subst df refl refl = df

transitive : {n : Level } { z y x : OD {suc n} } → z ∋ y → y ∋ x → z  ∋ x
transitive  {n} {z} {y} {x} z∋y x∋y  with  ordtrans ( c<→o< {suc n} {x} {y} x∋y ) (  c<→o< {suc n} {y} {z} z∋y ) 
... | t = lemma0 (lemma t) where
   lemma : ( od→ord x ) o< ( od→ord z ) → def ( ord→od ( od→ord z )) ( od→ord ( ord→od ( od→ord x )))
   lemma xo<z = o<→c< xo<z
   lemma0 :  def ( ord→od ( od→ord z )) ( od→ord ( ord→od ( od→ord x ))) →  def z (od→ord x)
   lemma0 dz  = def-subst {suc n} { ord→od ( od→ord z )} { od→ord ( ord→od ( od→ord x))} dz (oiso) (diso)

record Minimumo {n : Level } (x : Ordinal {n}) : Set (suc n) where
  field
     mino : Ordinal {n}
     min<x :  mino o< x

ominimal : {n : Level} → (x : Ordinal {n} ) → o∅ o< x → Minimumo {n} x
ominimal {n} record { lv = Zero ; ord = (Φ .0) } (case1 ())
ominimal {n} record { lv = Zero ; ord = (Φ .0) } (case2 ())
ominimal {n} record { lv = Zero ; ord = (OSuc .0 ord) } (case1 ())
ominimal {n} record { lv = Zero ; ord = (OSuc .0 ord) } (case2 Φ<) = record { mino = record { lv = Zero ; ord = Φ 0 } ; min<x = case2 Φ< }
ominimal {n} record { lv = (Suc lv) ; ord = (Φ .(Suc lv)) } (case1 (s≤s x)) = record { mino = record { lv = lv ; ord = Φ lv } ; min<x = case1 (s≤s ≤-refl)}
ominimal {n} record { lv = (Suc lv) ; ord = (Φ .(Suc lv)) } (case2 ())
ominimal {n} record { lv = (Suc lv) ; ord = (OSuc .(Suc lv) ord) } (case1 (s≤s x)) = record { mino = record { lv = (Suc lv) ; ord = ord } ; min<x = case2 s<refl}
ominimal {n} record { lv = (Suc lv) ; ord = (OSuc .(Suc lv) ord) } (case2 ())
ominimal {n} record { lv = (Suc lx) ; ord = (ℵ .lx) } (case1 (s≤s z≤n)) = record { mino = record { lv = Suc lx ; ord = Φ (Suc lx) } ; min<x = case2 ℵΦ<  }
ominimal {n} record { lv = (Suc lx) ; ord = (ℵ .lx) } (case2 ())

∅5 : {n : Level} →  { x : Ordinal {n} }  → ¬ ( x  ≡ o∅ {n} ) → o∅ {n} o< x
∅5 {n} {record { lv = Zero ; ord = (Φ .0) }} not = ⊥-elim (not refl) 
∅5 {n} {record { lv = Zero ; ord = (OSuc .0 ord) }} not = case2 Φ<
∅5 {n} {record { lv = (Suc lv) ; ord = ord }} not = case1 (s≤s z≤n)

∅8 : {n : Level} →  ( x : Ordinal {n} )  → ¬  x o< o∅ {n}
∅8 {n} x (case1 ())
∅8 {n} x (case2 ())

ord-iso : {n : Level} {y : Ordinal {n} } → record { lv = lv (od→ord (ord→od y)) ; ord = ord (od→ord (ord→od y)) } ≡ record { lv = lv y ; ord = ord y }
ord-iso = cong ( λ k → record { lv = lv k ; ord = ord k } ) diso

-- avoiding lv != Zero error
orefl : {n : Level} →  { x : OD {n} } → { y : Ordinal {n} } → od→ord x ≡ y → od→ord x ≡ y
orefl refl = refl

==-iso : {n : Level} →  { x y : OD {n} } → ord→od (od→ord x) == ord→od (od→ord y)  →  x == y
==-iso {n} {x} {y} eq = record {
      eq→ = λ d →  lemma ( eq→  eq (def-subst d (sym oiso) refl )) ;
      eq← = λ d →  lemma ( eq←  eq (def-subst d (sym oiso) refl ))  }
        where
           lemma : {x : OD {n} } {z : Ordinal {n}} → def (ord→od (od→ord x)) z → def x z
           lemma {x} {z} d = def-subst d oiso refl

=-iso : {n : Level } {x y : OD {suc n} } → (x == y) ≡ (ord→od (od→ord x) == y)
=-iso {_} {_} {y} = cong ( λ k → k == y ) (sym oiso)

ord→== : {n : Level} →  { x y : OD {n} } → od→ord x ≡  od→ord y →  x == y
ord→== {n} {x} {y} eq = ==-iso (lemma (od→ord x) (od→ord y) (orefl eq)) where
   lemma : ( ox oy : Ordinal {n} ) → ox ≡ oy →  (ord→od ox) == (ord→od oy)
   lemma ox ox  refl = eq-refl

o≡→== : {n : Level} →  { x y : Ordinal {n} } → x ≡  y →  ord→od x == ord→od y
o≡→== {n} {x} {.x} refl = eq-refl

∅7 : {n : Level} →  { x : OD {n} } → od→ord x ≡ o∅ {n} →  x  == od∅ {n}
∅7 {n} {x} eq = record { eq→ = e1 (orefl eq) ; eq← = e2 } where
   e2 : {y : Ordinal {n}} → def od∅ y → def x y 
   e2 {y} (lift ())
   e1 : {ox y : Ordinal {n}} → ox ≡ o∅ {n}  →  def x y → def od∅ y
   e1 {o∅} {y} refl x>y = lift ( ∅8 y (o<-subst (c<→o< {n} {ord→od y} {x} (def-subst {n} {x} {y} x>y refl (sym diso))) ord-iso eq ))  

=→¬< : {x : Nat  } → ¬ ( x < x )
=→¬< {Zero} ()
=→¬< {Suc x} (s≤s lt) = =→¬< lt

>→¬< : {x y : Nat  } → (x < y ) → ¬ ( y < x )
>→¬< (s≤s x<y) (s≤s y<x) = >→¬< x<y y<x

c≤-refl : {n : Level} →  ( x : OD {n} ) → x c≤ x
c≤-refl x = case1 refl

o<> : {n : Level } ( ox oy : Ordinal {n}) → ox o<  oy  → oy o< ox  →  ⊥
o<> ox oy (case1 x<y) (case1 y<x) = >→¬< x<y y<x
o<> ox oy (case1 x<y) (case2 y<x) with d<→lv  y<x
... | refl = =→¬< x<y
o<> ox oy (case2 x<y) (case1 y<x) with d<→lv  x<y
... | refl = =→¬< y<x
o<> ox oy (case2 x<y) (case2 y<x) with d<→lv  x<y
... | refl = trio<> x<y y<x

o<¬≡ : {n : Level } ( ox oy : Ordinal {n}) → ox ≡ oy  → ox o< oy  → ⊥
o<¬≡ ox ox refl (case1 lt) =  =→¬< lt
o<¬≡ ox ox refl (case2 (s< lt)) = trio<≡ refl lt

o<→o> : {n : Level} →  { x y : OD {n} } →  (x == y) → (od→ord x ) o< ( od→ord y) → ⊥
o<→o> {n} {x} {y} record { eq→ = xy ; eq← = yx } (case1 lt) with
     yx (def-subst {n} {ord→od (od→ord y)} {od→ord (ord→od (od→ord x))} (o<→c< (case1 lt )) oiso diso )
... | oyx with o<¬≡ (od→ord x) (od→ord x) refl (c<→o< oyx )
... | ()
o<→o> {n} {x} {y} record { eq→ = xy ; eq← = yx } (case2 lt) with
     yx (def-subst {n} {ord→od (od→ord y)} {od→ord (ord→od (od→ord x))} (o<→c< (case2 lt )) oiso diso )
... | oyx with o<¬≡ (od→ord x) (od→ord x) refl (c<→o< oyx )
... | ()

o<→¬== : {n : Level} →  { x y : OD {n} } → (od→ord x ) o< ( od→ord y) →  ¬ (x == y )
o<→¬== {n} {x} {y} lt eq = o<→o> eq lt

o<→¬c> : {n : Level} →  { x y : OD {n} } → (od→ord x ) o< ( od→ord y) →  ¬ (y c< x )
o<→¬c> {n} {x} {y} olt clt = o<> (od→ord x) (od→ord y) olt (c<→o< clt ) where

o≡→¬c< : {n : Level} →  { x y : OD {n} } →  (od→ord x ) ≡ ( od→ord y) →   ¬ x c< y
o≡→¬c< {n} {x} {y} oeq lt  = o<¬≡ (od→ord x) (od→ord y) (orefl oeq ) (c<→o< lt) 

tri-c< : {n : Level} →  Trichotomous _==_ (_c<_ {suc n})
tri-c< {n} x y with trio< {n} (od→ord x) (od→ord y) 
tri-c< {n} x y | tri< a ¬b ¬c = tri< (def-subst (o<→c< a) oiso diso) (o<→¬== a) ( o<→¬c> a )
tri-c< {n} x y | tri≈ ¬a b ¬c = tri≈ (o≡→¬c< b) (ord→== b) (o≡→¬c< (sym b))
tri-c< {n} x y | tri> ¬a ¬b c = tri>  ( o<→¬c> c) (λ eq → o<→¬== c (eq-sym eq ) ) (def-subst (o<→c< c) oiso diso)

c<> : {n : Level } { x y : OD {suc n}} → x c<  y  → y c< x  →  ⊥
c<> {n} {x} {y} x<y y<x with tri-c< x y
c<> {n} {x} {y} x<y y<x | tri< a ¬b ¬c = ¬c y<x
c<> {n} {x} {y} x<y y<x | tri≈ ¬a b ¬c = o<→o> b ( c<→o< x<y )
c<> {n} {x} {y} x<y y<x | tri> ¬a ¬b c = ¬a x<y

∅2 : {n : Level} →  { x : OD {n} } → o∅ {n} o<  od→ord x → ¬ ( x  == od∅ {n} )
∅2 {n} {x} lt record { eq→ = eq→ ; eq← = eq← } with ominimal (od→ord x ) lt
... | min with eq→ ( def-subst (o<→c< (Minimumo.min<x min)) oiso refl )
... | ()
       
∅0 : {n : Level} →  { x : Ordinal {n} } → o∅ {n} o< x → ¬ ( ord→od x  == od∅ {n} )
∅0 {n} {x} lt record { eq→ = eq→ ; eq← = eq← } with ominimal x lt
... | min with eq→ (o<→c< (Minimumo.min<x min))
... | ()

∅< : {n : Level} →  { x y : OD {n} } → def x (od→ord y ) → ¬ (  x  == od∅ {n} )
∅< {n} {x} {y} d eq with eq→ eq d
∅< {n} {x} {y} d eq | lift ()
       

is-od∅ : {n : Level} →  ( x : OD {suc n} ) → Dec ( x == od∅ {suc n} )
is-od∅ {n} x with trio< {n} (od→ord x) (o∅ {suc n})
is-od∅ {n} x | tri≈ ¬a b ¬c = yes ( ∅7 (orefl b) ) 
is-od∅ {n} x | tri< (case1 ()) ¬b ¬c
is-od∅ {n} x | tri< (case2 ()) ¬b ¬c
is-od∅ {n} x | tri> ¬a ¬b c = no ( ∅2 c )

is-∋ : {n : Level} →  ( x y : OD {suc n} ) → Dec ( x ∋ y )
is-∋ {n} x y with tri-c< x y
is-∋ {n} x y | tri< a ¬b ¬c = no ¬c
is-∋ {n} x y | tri≈ ¬a b ¬c = no ¬c
is-∋ {n} x y | tri> ¬a ¬b c = yes c

is-o∅ : {n : Level} →  ( x : Ordinal {suc n} ) → Dec ( x ≡ o∅ {suc n} )
is-o∅ {n} record { lv = Zero ; ord = (Φ .0) } = yes refl
is-o∅ {n} record { lv = Zero ; ord = (OSuc .0 ord₁) } = no ( λ () )
is-o∅ {n} record { lv = (Suc lv₁) ; ord = ord } = no (λ())

open _∧_

∅9 : {n : Level} → {x : OD {n} } → ¬ x == od∅ → o∅ o< od→ord x
∅9 {_} {x} not = ∅5  lemma where
   lemma : ¬ od→ord x ≡ o∅
   lemma eq = not ( ∅7  eq )

∅10 : {n : Level} →  {ox : Ordinal {n}} → (not : ¬ (ord→od ox == od∅)) → o∅ o< ox
∅10 {n} {ox} not = subst (λ k → o∅ o< k) diso (∅9 not)

¬∅=→∅∈ :  {n : Level} →  { x : OD {suc n} } → ¬ (  x  == od∅ {suc n} ) → x ∋ od∅ {suc n} 
¬∅=→∅∈  {n} {x} ne = def-subst (lemma (od→ord x) (subst (λ k → ¬ (k == od∅ {suc n} )) (sym oiso) ne )) oiso refl where
     lemma : (ox : Ordinal {suc n}) →  ¬ (ord→od  ox  == od∅ {suc n} ) → ord→od ox ∋ od∅ {suc n}
     lemma ox ne with is-o∅ ox
     lemma ox ne | yes refl with ne ( ord→== lemma1 ) where
         lemma1 : od→ord (ord→od o∅) ≡ od→ord od∅
         lemma1 = cong ( λ k → od→ord k ) o∅→od∅
     lemma o∅ ne | yes refl | ()
     lemma ox ne | no ¬p = subst ( λ k → def (ord→od ox) (od→ord k) ) o∅→od∅ (o<→c< (∅5 ¬p))  

-- ∃-set :  {n : Level} → ( x : OD {suc n} ) → ( ψ :  OD {suc n} → Set (suc n) ) → Set (suc n)
-- ∃-set = {!!}

-- postulate f-extensionality : { n : Level}  → Relation.Binary.PropositionalEquality.Extensionality (suc (suc n)) (suc (suc n ))

-- ==∅→≡ :  {n : Level} →  { x : OD {suc n} } → (  x  == od∅ {suc n} ) → x ≡ od∅ {suc n} 
-- ==∅→≡ {n} {x} eq = cong (  λ k → record { def = k } ) (trans {!!} ∅-base-def ) where


open import Relation.Binary.HeterogeneousEquality as HE using (_≅_ ) 

OD→ZF : {n : Level} → ZF {suc (suc n)} {suc n}
OD→ZF {n}  = record { 
    ZFSet = OD {suc n}
    ; _∋_ = _∋_ 
    ; _≈_ = _==_ 
    ; ∅  = od∅
    ; _,_ = _,_
    ; Union = Union
    ; Power = Power
    ; Select = Select
    ; Replace = Replace
    ; infinite = record { def = λ x → x ≡ record { lv = Suc Zero ; ord = ℵ Zero  }  }
    ; isZF = isZF 
 } where
    Replace : OD {suc n} → (OD {suc n} → OD {suc n} ) → OD {suc n}
    Replace X ψ = sup-od ψ
    Select : OD {suc n} → (OD {suc n} → Set (suc n) ) → OD {suc n}
    Select X ψ = record { def = λ x →  ( def X  x ∧  ψ ( ord→od x )) } 
    _,_ : OD {suc n} → OD {suc n} → OD {suc n}
    x , y = record { def = λ z → ( (z ≡ od→ord x ) ∨ ( z ≡ od→ord y )) }
    Union : OD {suc n} → OD {suc n}
    Union U = record { def = λ y → osuc y o< (od→ord U) }
    Power : OD {suc n} → OD {suc n}
    Power x = record { def = λ y → (z : Ordinal {suc n} ) → ( def x y ∧ def (ord→od z) y )  }
    ZFSet = OD {suc n}
    _∈_ : ( A B : ZFSet  ) → Set (suc n)
    A ∈ B = B ∋ A
    _⊆_ : ( A B : ZFSet  ) → ∀{ x : ZFSet } →  Set (suc n)
    _⊆_ A B {x} = A ∋ x →  B ∋ x
    _∩_ : ( A B : ZFSet  ) → ZFSet
    A ∩ B = Select (A , B) (  λ x → ( A ∋ x ) ∧ (B ∋ x) )
    _∪_ : ( A B : ZFSet  ) → ZFSet
    A ∪ B = Select (A , B) (  λ x → (A ∋ x)  ∨ ( B ∋ x ) )
    infixr  200 _∈_
    infixr  230 _∩_ _∪_
    infixr  220 _⊆_
    isZF : IsZF (OD {suc n})  _∋_  _==_ od∅ _,_ Union Power Select Replace (record { def = λ x → x ≡ record { lv = Suc Zero ; ord = ℵ Zero }  })
    isZF = record {
           isEquivalence  = record { refl = eq-refl ; sym = eq-sym; trans = eq-trans }
       ;   pair  = pair
       ;   union-u = union-u
       ;   union→ = union→
       ;   union← = union←
       ;   empty = empty
       ;   power→ = {!!}
       ;   power← = {!!}
       ;   extensionality = {!!}
       ;   minimul = minimul
       ;   regularity = regularity
       ;   infinity∅ = {!!}
       ;   infinity = {!!}
       ;   selection = λ {ψ} {X} {y} → selection {ψ} {X} {y}
       ;   replacement = {!!}
     } where
         open _∧_ 
         open Minimumo
         pair : (A B : OD {suc n} ) → ((A , B) ∋ A) ∧  ((A , B) ∋ B)
         proj1 (pair A B ) =  case1 refl 
         proj2 (pair A B ) =  case2 refl 
         empty : (x : OD {suc n} ) → ¬  (od∅ ∋ x)
         empty x ()
         union-u : (X z : OD {suc n}) → Union X ∋ z → OD {suc n}
         union-u X z U>z = ord→od ( osuc ( od→ord z ) )
         union-lemma-u : {X z : OD {suc n}} → (U>z : Union X ∋ z ) → union-u X z U>z  ∋ z
         union-lemma-u {X} {z} U>z = lemma <-osuc where
             lemma : {oz ooz : Ordinal {suc n}} → oz o< ooz → def (ord→od ooz) oz
             lemma {oz} {ooz} lt = def-subst {suc n} {ord→od  ooz} (o<→c< lt) refl diso
         union→ :  (X z u : OD) → (X ∋ u) ∧ (u ∋ z) → Union X ∋ z
         union→ X y u xx with trio< ( od→ord u ) ( osuc ( od→ord y ))
         union→ X y u xx | tri< a ¬b ¬c with  osuc-< a (c<→o< (proj2 xx))
         union→ X y u xx | tri< a ¬b ¬c | ()
         union→ X y u xx | tri≈ ¬a b ¬c = lemma b (c<→o< (proj1 xx )) where
             lemma : {oX ou ooy : Ordinal {suc n}} →  ou ≡ ooy  → ou o< oX   → ooy  o< oX
             lemma refl lt = lt
         union→ X y u xx | tri> ¬a ¬b c = ordtrans {suc n} {osuc ( od→ord y )} {od→ord u} {od→ord X} c ( c<→o< (proj1 xx )) 
         union← :  (X z : OD) (X∋z : Union X ∋ z) → (X ∋ union-u X z X∋z) ∧ (union-u X z X∋z ∋ z )
         union← X z X∋z = record { proj1 = def-subst {suc n} (o<→c< X∋z) oiso refl ; proj2 = union-lemma-u X∋z } 
         ψiso :  {ψ : OD {suc n} → Set (suc n)} {x y : OD {suc n}} → ψ x → x ≡ y   → ψ y
         ψiso {ψ} t refl = t
         selection : {ψ : OD → Set (suc n)} {X y : OD} → ((X ∋ y) ∧ ψ y) ⇔ (Select X ψ ∋ y)
         selection {ψ} {X} {y} = record {
              proj1 = λ cond → record { proj1 = proj1 cond ; proj2 = ψiso {ψ} (proj2 cond) (sym oiso)  }
            ; proj2 = λ select → record { proj1 = proj1 select  ; proj2 =  ψiso {ψ} (proj2 select) oiso  }
           }
         ∅-iso :  {x : OD} → ¬ (x == od∅) → ¬ ((ord→od (od→ord x)) == od∅) 
         ∅-iso {x} neq = subst (λ k → ¬ k) (=-iso {n} ) neq  
         minimul : (x : OD {suc n} ) → ¬ (x == od∅ )→ OD {suc n} 
         minimul x  not = od∅   
         regularity :  (x : OD) (not : ¬ (x == od∅)) →
            (x ∋ minimul x not) ∧ (Select (minimul x not) (λ x₁ → (minimul x not ∋ x₁) ∧ (x ∋ x₁)) == od∅)
         proj1 (regularity x not ) = ¬∅=→∅∈ not 
         proj2 (regularity x not ) = record { eq→ = reg ; eq← = λ () } where
            reg : {y : Ordinal} → def (Select (minimul x not) (λ x₂ → (minimul x not ∋ x₂) ∧ (x ∋ x₂))) y → def od∅ y
            reg {y} t with proj1 t
            ... | x∈∅ = x∈∅