Mercurial > hg > Members > kono > os9 > sbc09

comparison CoCoOS9/level2v3/CMDS/askmontype.asm @ 31:bd2b07db8917 cocoos9lv2v3

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
CoCoOS9 version
author Shinji KONO <kono@ie.u-ryukyu.ac.jp>
date Sat, 14 Jul 2018 15:16:13 +0900
parents
children
comparison
equal deleted inserted replaced
30:7b1b25ff010a 31:bd2b07db8917
1 ********************************************************************
2 * AskMonType - Query based monitor type utility
3 *
4 * $Id: askmontype.asm,v 1.1.1.1 2001/02/21 23:30:54 boisy Exp $
5 *
6 * Ed. Comments Who YY/MM/DD
7 * ------------------------------------------------------------------
8 * 1 Created BG 97/??/??
9
10 nam AskMonType
11 ttl Query based monitor type utility
12
13 ifp1
14 use defsfile
15 endc
16
17 tylg set Prgrm+Objct
18 atrv set ReEnt+rev
19 rev set $01
20 edition set 1
21
22 mod eom,name,tylg,atrv,start,size
23
24 key rmb 1
25 orgopts rmb 32
26 modopts rmb 32
27 stack rmb 200
28 size equ .
29
30 name fcs /AskMonType/
31 fcb edition
32
33 start leax >CurOff,pcr
34 ldy #CurOffL
35 lbsr WriteMsg
36 clra
37 clrb
38 leax orgopts,u
39 os9 I$GetStt
40 leax modopts,u
41 os9 I$GetStt
42 clr 4,x
43 clr 16,x
44 clr 17,x
45 clrb
46 os9 I$SetStt
47 AskMon leax >MonSelct,pcr
48 ldy #MonSelL
49 lbsr WriteMsg
50 AskMon2 lbsr ReadKey
51 cmpa #'1
52 beq DoTV
53 cmpa #'2
54 beq DoMono
55 cmpa #'3
56 beq DoRGB
57 leax >Bell,pcr
58 ldy #BellL
59 lbsr WriteMsg
60 bra AskMon2
61 DoTV ldx #$0000 TV/composite monitor
62 bra ChgMon
63 DoMono ldx #$0002 monochrome monitor
64 bra ChgMon
65 DoRGB ldx #$0001 RGB monitor
66 ChgMon ldd #$01*256+SS.Montr
67 os9 I$SetStt make the monitor setting
68 leax >CurOn,pcr
69 ldy #CurOnL
70 lbsr WriteMsg
71 leax orgopts,u
72 clra
73 clrb
74 os9 I$SetStt
75 clrb
76 os9 F$Exit
77
78 ReadKey pshs y,x,b
79 clra stdin
80 leax key,u
81 ldy #1
82 os9 I$Read
83 lda key,u
84 puls pc,y,x,b
85
86 WriteMsg pshs y,x,b,a
87 lda #1 stdout
88 os9 I$Write
89 puls pc,y,x,b,a
90
91
92 CurOff fdb $0520
93 CurOffL equ *-CurOff
94 CurOn fdb $0521
95 CurOnL equ *-CurOn
96
97 MonSelct fcb C$FORM
98 fcb $02,$20,$22
99 fcc / SELECT YOUR DISPLAY TYPE/
100 fcb C$LF,C$CR,C$LF,C$CR,C$LF,C$CR
101 fcc " (1) TV/Composite Monitor"
102 fcb C$LF,C$CR,C$LF,C$CR
103 fcc / (2) Monochrome Monitor/
104 fcb C$LF,C$CR,C$LF,C$CR
105 fcc / (3) RGB Monitor/
106 fcb C$LF,C$CR
107 MonSelL equ *-MonSelct
108
109 Bell fcb C$BELL
110 BellL equ *-Bell
111
112 emod
113 eom equ *
114 end