view build.gradle @ 0:4689cc86d6cb

create TreeViewer2 Repository
author Yu Taninari <you@cr.ie.u-ryukyu.ac.jp>
date Tue, 03 Jul 2012 13:20:49 +0900
parents
children 1b81deb0abb3 17b702648079
line wrap: on
line source

apply plugin:'java'
apply plugin: 'eclipse'

sourceCompatibility = 1.6
targetCompatibility = 1.6
version = '2.5.0'

baseName = 'tightvnc-jviewer'

defaultTasks 'clean', 'dist'

configurations {
	viewerSwingCompile { extendsFrom compile }
	viewerSwingRuntime { extendsFrom viewerSwingCompile, runtime }
}

sourceSets {
	viewerSwing {
		java {
			srcDir 'src/viewer_swing/java'
		}
		resources {
			srcDir 'src/viewer_swing/resources'
		}
	}
	main {
		java.srcDirs += viewerSwing.java.srcDirs
		resources.srcDirs += viewerSwing.resources.srcDirs
	}
}

jar {
	baseName = project.baseName
	version = null
    manifest {
        attributes 'Main-Class': 'com.glavsoft.viewer.Viewer'
        attributes 'Implementation-Version': "${project.version}"
    }
}

repositories {
    mavenCentral()
}

dependencies {
    testCompile group: 'junit', name: 'junit', version: '4.+'
    archives fileTree(dir: 'src/web', include: '*.html')
}

uploadArchives {
    repositories {
		add(new org.apache.ivy.plugins.resolver.FileSystemResolver()) {
			name = 'repo'
			addArtifactPattern "$projectDir/dist/${project.baseName}-${project.version}/${project.baseName}.[ext]"
			descriptor = 'optional'
			checkmodified = true
		}
	}
	uploadDescriptor = false
}

task dist(dependsOn: uploadArchives) << {
	otherFilesUpload("$projectDir/dist/${project.baseName}-${project.version}")
}
def otherFilesUpload(repoDir) {
	copy {
		from 'src/web'
		include '*-applet-*.html'
		expand (['archive_name' : project.baseName])
		into repoDir
	}
}